FQP6N90C

New About Yours API Help
2.1 KB, Plain text
**************** Power Discrete MOSFET Electrical Circuit Model *****************
** Product Name: FQP6N90C
** 900V N-Channel MOSFET and TO-220
** Model Type: BSIM3V3
**-------------------------------------------------------------------------------
.SUBCKT FQPF6N90C 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5    DbodyMOD
Dbreak 5 11  DbreakMOD
Ebreak 11 7 17 7 900
Lgate 1 9    1.125e-9
Ldrain 2 5   1.440e-9
Lsource 3 7  9.106e-10
RLgate 1 9   11.25
RLdrain 2 5  14.4
RLsource 3 7 9.11
Rgate 9 6    0.5
It 7 17      1
Rbreak 17 7  RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.18e-3 TC2=-1.15e-6)
.MODEL DbodyMOD D (IS=3.45e-9  N=1.5      RS=8.44e-3   TRS1=3.8e-3 TRS2=5.8e-6 
+ CJO=1.38e-09     M=0.50      VJ=0.85    TT=1.59e-6   XTI=3       EG=1.154)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1.0e-3 TRS2=5.0e-6)
Rdrain 5 16 RdrainMOD 1.84
.MODEL RdrainMOD RES (TC1=8.8e-3 TC2=2.46e-5)
M_BSIM3 16 6 7 7 Bsim3 W=1.08 L=2.0e-6 NRS=1
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 PARAMCHK=1 NQSMOD=0
+ TOX=970e-10    XJ=1.4e-6      NCH=1.7e17      UA=1.6e-9
+ U0=700         VSAT=1.0e5     DROUT=3.0       PVAG=5
+ DELTA=0.10     PSCBE2=0       RSH=1.0e-3      PDIBLC2=1e-7
+ VTH0=4.10      VOFF=-0.1      NFACTOR=1.1     
+ LINT=5.90e-7   DLC=5.90e-7    FC=0.5
+ CGSO=9.32e-10  CGSL=0         CGDO=8.65e-12  
+ CGDL=9.23e-10  CJ=0           CF=0 
+ CKAPPA=0.13    KT1=-2.07      KT2=0
+ UA1=1.02e-10   NJ=10 )
.ENDS

******************** Power Discrete MOSFET Thermal Model ************************
** 900V N-Channel MOSFET and TO-220
**-------------------------------------------------------------------------------
.SUBCKT FQP6N90C_Thermal TH TL
CTHERM1 TH 6 2.04e-5
CTHERM2 6 5  2.64e-3
CTHERM3 5 4  1.22e-2
CTHERM4 4 3  3.54e-2
CTHERM5 3 2  5.02e-1
CTHERM6 2 TL 8.02e-1
RTHERM1 TH 6 3.80e-3
RTHERM2 6 5  7.20e-3
RTHERM3 5 4  1.80e-2
RTHERM4 4 3  1.88e-1
RTHERM5 3 2  2.24e-1
RTHERM6 2 TL 3.09e-1
.ENDS FQP6N90C_Thermal
**-------------------------------------------------------------------------------
** Creation: Oct.-06-2009   Rev.: 0.0
** Fairchild Semiconductor
Pasted 9 months, 3 weeks ago — Expires in 73 days
URL: http://dpaste.com/0QDAYRJ